s3c2410中斷處理程序

s3c2410中斷程序
在此要注意的是區(qū)別中斷向量表和異常向量表。中斷發(fā)生后總是從IRQ 或者FIQ 異常入口處進入，然后跳轉(zhuǎn)到相應(yīng)的異常處理程序處執(zhí)行，這個異常處理程序一般都是進行查找中斷向量表的操作，然后調(diào)用中斷處理程序。
以下是在應(yīng)用中中斷處理實現(xiàn)的過程：從中不難體會到中斷的處理過程。
定義中斷向量表的物理地址：
代碼
.equ pISR_DABORT , (_ISR_STARTADDRESS+0x10)
.equ pISR_RESERVED, (_ISR_STARTADDRESS+0x14)
.equ pISR_IRQ , (_ISR_STARTADDRESS+0x18)
.equ pISR_FIQ , (_ISR_STARTADDRESS+0x1c) //異常向量表
……………………………………………………………………
.equ pISR_EINT0 , (_ISR_STARTADDRESS+0x20) //中斷向量表
.equ pISR_EINT1 , (_ISR_STARTADDRESS+0x24)
.equ pISR_EINT2 , (_ISR_STARTADDRESS+0x28)
.equ pISR_EINT3 , (_ISR_STARTADDRESS+0x2c)
將中斷處理程序入口地址放入中斷向量表：
代碼
pISR_EINT0 = (unsigned int)isrEINT0; // isrEINT0 中斷處理程序
pISR_EINT1 = (unsigned int)isrEINT1;
定義中斷處理程序：
代碼
.extern Interrupt_Rbutton
.global isrEINT0
isrEINT0:
IRQHandle Interrupt_Rbutton
定義異常向量表：
代碼
b HandlerUndef /* handler for Undefined mode */
b HandlerSWI /* handler for SWI interrupt */
b HandlerPabort /* handler for PAbort */
b HandlerDabort /* handler for DAbort */
.long FileIDTable /* id */
b HandlerIRQ /* handler for IRQ interrupt */
b HandlerFIQ
定義異常處理函數(shù)：
代碼
HandlerFIQ: HANDLER HandleFIQ
HandlerIRQ: HANDLER HandleIRQ
HandlerUndef: HANDLER HandleUndef
HandlerSWI: HANDLER HandleSWI
HandlerDabort: HANDLER HandleDabort
HandlerPabort: HANDLER HandlePabort
異常處理宏HANDLER的定義：
代碼
.macro HANDLER HandleLabel
sub sp,sp,#4 /* decrement sp(to store jump address) */
stmfd sp!,{r0} /* PUSH the work register to stack(lr does't push bec
ause it return to original address) */
ldr r0,=HandleLabel /* load the address of HandleXXX to r0 */
ldr r0,[r0] /* load the contents(service routine start address) of
HandleXXX */
str r0,[sp,#4] /* store the contents(ISR) of HandleXXX to stack */
ldmfd sp!,{r0,pc} /* POP the work register and pc(jump to ISR) */
.endm
定義IRQ 中斷處理宏IRQHandle：
代碼
.macro IRQHandle isrHandle:
stmdb sp!, {r0-r11, ip, lr} /* save r0-r11, ip, lr */
ldr r0, =isrHandle
mov lr, pc
bx r0 /* jump to user_handle(void) */
ldmia sp!, {r0-r11, ip, lr} /* restore r0, ip, lr */
subs pc, r14, #4 /* return from interrupt */
.endm
申明IRQ 異常的服務(wù)程序為：IsrIRQ，即，發(fā)生IRQ 異常時，執(zhí)行“b HandlerIRQ”即是
運行IsrIRQ代碼：
代碼
ldr r0,=HandleIRQ @ This routine is needed
ldr r1,=IsrIRQ @ if there isn't 'subs pc,lr,#4' at 0x18, 0x1c
str r1,[r0]
IRQ 異常處理程序：
代碼
IsrIRQ:
sub sp,sp,#4 @ reserved for PC
stmfd sp!,{r8-r9}
ldr r9,=INTOFFSET
ldr r9,[r9]
ldr r8,=HandleEINT0
add r8,r8,r9,lsl #2
ldr r8,[r8]
str r8,[sp,#8]
ldmfd sp!,{r8-r9,pc}
在嵌入式系統(tǒng)中異常向量表和中斷向量表都是存于FLASH起始的一段空間中。而異常處理和中斷處理程序都是運行在RAM中的。

由上可以知道，當一個IRQ 中斷發(fā)生時，CPU將從0X18（IRQ 異常入口地址）取指執(zhí)行，在這一步PC 的跳轉(zhuǎn)是有硬件實現(xiàn)的。在入口0x18 地址處放的是一條跳轉(zhuǎn)指令，這條指令將跳到IRQ 異常處理程序運行，IRQ 異常處理程序主要是根據(jù)中斷源查找中斷向量表。獲得中斷入口地址后，接著CPU 跳轉(zhuǎn)中斷處理程序運行。