Linux下如何使用CMake編譯程序

今天分享一篇關(guān)于cmake 的相關(guān)文章，通過(guò)這個(gè)工具可以生成本地的Makefile。讓我們不用去編寫復(fù)雜的Makefile。

引言

CMake是開(kāi)源、跨平臺(tái)的構(gòu)建工具，可以讓我們通過(guò)編寫簡(jiǎn)單的配置文件去生成本地的Makefile，這個(gè)配置文件是獨(dú)立于運(yùn)行平臺(tái)和編譯器的，這樣就不用親自去編寫Makefile了，而且配置文件可以直接拿到其它平臺(tái)上使用，無(wú)需修改，非常方便。

本文主要講述在Linux下如何使用CMake來(lái)編譯我們的程序。

一 環(huán)境搭建

我使用的是ubuntu18.04，安裝cmake使用如下命令：

sudo apt install cmake

安裝完成后，在終端下輸入:

cmake -version

查看cmake版本

這樣cmake就安裝好了。

二 簡(jiǎn)單入門

首先讓我們從最簡(jiǎn)單的代碼入手，先來(lái)體驗(yàn)下cmake是如何操作的。

2.1 項(xiàng)目結(jié)構(gòu)

2.2 示例源碼

打開(kāi)終端，輸入：

touch main.c CMakeLists.txt

編寫main.c，如下：

#include

int main(void)
{
printf("Hello World\n");
return 0;
}

然后在main.c同級(jí)目錄下編寫CMakeLists.txt，內(nèi)容如下：

cmake_minimum_required (VERSION 2.8)

project (demo)

add_executable(main main.c)

2.3 運(yùn)行查看

在終端下切到main.c所在的目錄下，然后輸入以下命令運(yùn)行cmake：

cmake .

輸出結(jié)果如下：

ps:此時(shí)，建議留意一下這個(gè)文件夾下多生成的文件都有哪些。

可以看到成功生成了Makefile，還有一些cmake運(yùn)行時(shí)自動(dòng)生成的文件。

然后在終端下輸入make：

可以看到執(zhí)行cmake生成的Makefile可以顯示進(jìn)度，并帶顏色。再看下目錄下的文件：

可以看到我們需要的可執(zhí)行文件main也成功生成了！

然后運(yùn)行main：

運(yùn)行成功！

PS：如果想重新生成main，輸入make clean就可以刪除main這個(gè)文件。然后重新make就行。需要注意的是：我希望你著重看一下這時(shí)候這個(gè)文件夾下都有哪些文件。

三 編譯多個(gè)源文件

3.1 在同一個(gè)目錄下有多個(gè)源文件

3.1.1 簡(jiǎn)單版本

接下來(lái)進(jìn)入稍微復(fù)雜的例子：在同一個(gè)目錄下有多個(gè)源文件。

3.1.1.1 項(xiàng)目結(jié)構(gòu)

3.1.1.2 示例代碼

首先刪除之前的文件：

rm -rf CMakeFiles CMakeCache.txt cmake_install.cmake Makefile main

在之前的目錄下添加2個(gè)文件，testFunc.c和testFunc.h:

touch testFunc.c testFunc.h

添加完后整體文件結(jié)構(gòu)如下：

testFunc.c

testFunc.h

/*
** testFunc.h
*/

#ifndef _TEST_FUNC_H_
#define _TEST_FUNC_H_

void func(int data);

#endif

修改main.c，調(diào)用testFunc.h里聲明的函數(shù)func()：

main.c

#include

#include "testFunc.h"

int main(void)
{
func(100);
return 0;
}

修改CMakeLists.txt，在add_executable的參數(shù)里把testFunc.c加進(jìn)來(lái):

CMakeLists.txt

cmake_minimum_required (VERSION 2.8)

project (demo)

add_executable(main main.c testFunc.c)

3.1.1.3 運(yùn)行查看

cmake . make

然后運(yùn)行查看：

運(yùn)行成功！

可以類推，如果在同一目錄下有多個(gè)源文件，那么只要在add_executable里把所有源文件都添加進(jìn)去就可以了。

但是如果有一百個(gè)源文件，再這樣做就有點(diǎn)坑了，無(wú)法體現(xiàn)cmake的優(yōu)越性。因此cmake提供了一個(gè)命令可以把指定目錄下所有的源文件存儲(chǔ)在一個(gè)變量中，這個(gè)命令就是

aux_source_directory(dir var)

第一個(gè)參數(shù)dir是指定目錄，第二個(gè)參數(shù)var是用于存放源文件列表的變量。

接下來(lái)寫個(gè)進(jìn)階版的demo使用一下這個(gè)變量。

3.1.2 進(jìn)階版本

3.1.2.1 項(xiàng)目結(jié)構(gòu)

3.1.2.2 示例源碼

刪除無(wú)關(guān)文件

rm -rf CMakeFiles CMakeCache.txt cmake_install.cmake main Makefile

創(chuàng)建文件：

touch testFunc1.c testFunc1.h

testFunc1.c

/*
** testFunc1.c
*/

#include
#include "testFunc1.h"

void func1(int data)
{
printf("data is %d\n", data);
}

testFunc1.h

/*
** testFunc1.h
*/

#ifndef _TEST_FUNC1_H_
#define _TEST_FUNC1_H_

void func1(int data);

#endif

再修改main.c，調(diào)用testFunc1.h里聲明的函數(shù)func1()：

main.c

#include

#include "testFunc.h"
#include "testFunc1.h"

int main(void)
{
func(100);
func1(200);

return 0;
}

修改CMakeLists.txt：

CMakeLists.txt

cmake_minimum_required (VERSION 2.8)

project (demo)

aux_source_directory(. SRC_LIST)

add_executable(main ${SRC_LIST})

使用aux_source_directory把當(dāng)前目錄下的源文件存列表存放到變量SRC_LIST里;

然后在add_executable里調(diào)用SRC_LIST（注意調(diào)用變量時(shí)的寫法）。

3.1.2.3 運(yùn)行查看

再次執(zhí)行cmake和make，并運(yùn)行main:

可以看到運(yùn)行成功了。

aux_source_directory()也存在弊端，它會(huì)把指定目錄下的所有源文件都加進(jìn)來(lái)，可能會(huì)加入一些我們不需要的文件，此時(shí)我們可以使用set命令去新建變量來(lái)存放需要的源文件，如下：

cmake_minimum_required (VERSION 2.8)

project (demo)

set( SRC_LIST
./main.c
./testFunc1.c
./testFunc.c)

add_executable(main ${SRC_LIST})

3.2 在不同目錄下有多個(gè)源文件

一般來(lái)說(shuō)，當(dāng)程序文件比較多時(shí)，我們會(huì)進(jìn)行分類管理，把代碼根據(jù)功能放在不同的目錄下，這樣方便查找。那么這種情況下如何編寫CMakeLists.txt呢？

3.2.1 項(xiàng)目結(jié)構(gòu)

我們把之前的源文件整理一下（新建2個(gè)目錄test_func和test_func1）：

rm -rf CMakeFiles CMakeCache.txt cmake_install.cmake main Makefile

整理好后整體文件結(jié)構(gòu)如下：

把之前的testFunc.c和testFunc.h放到test_func目錄下，testFunc1.c和testFunc1.h則放到test_func1目錄下。

3.2.2 示例源碼

其中，CMakeLists.txt和main.c在同一目錄下，內(nèi)容修改成如下所示：

cmake_minimum_required (VERSION 2.8)

project (demo)

include_directories (test_func test_func1)

aux_source_directory (test_func SRC_LIST)
aux_source_directory (test_func1 SRC_LIST1)

add_executable (main main.c ${SRC_LIST} ${SRC_LIST1})

這里出現(xiàn)了一個(gè)新的命令：include_directories。

該命令是用來(lái)向工程添加多個(gè)指定頭文件的搜索路徑，路徑之間用空格分隔。

因?yàn)閙ain.c里include了testFunc.h和testFunc1.h，如果沒(méi)有這個(gè)命令來(lái)指定頭文件所在位置，就會(huì)無(wú)法編譯。當(dāng)然，也可以在main.c里使用include來(lái)指定路徑，如下

#include "test_func/testFunc.h"
#include "test_func1/testFunc1.h"

只是這種寫法不好看。另外，我們使用了2次aux_source_directory，因?yàn)樵次募植荚?個(gè)目錄下，所以添加2次。

3.2.2 運(yùn)行查看

四 項(xiàng)目級(jí)的組織結(jié)構(gòu)

正規(guī)一點(diǎn)來(lái)說(shuō)，一般會(huì)把源文件放到src目錄下，把頭文件放入到include文件下，生成的對(duì)象文件放入到build目錄下，最終輸出的可執(zhí)行程序文件會(huì)放到bin目錄下，這樣整個(gè)結(jié)構(gòu)更加清晰。

4.1 項(xiàng)目結(jié)構(gòu)

讓我們把前面的文件再次重新組織下：

4.2 示例源碼

修改CMakeLists.txt：

CMakeLists.txt

cmake_minimum_required (VERSION 2.8)

project (demo)

add_subdirectory (src)

add_subdirectory：這個(gè)語(yǔ)句的作用是增加編譯子目錄。其基本語(yǔ)法格式是：

add_subdirectory(source_dir [binary_dir] [EXCLUDE_FROM_ALL])

一共有三個(gè)參數(shù)，后兩個(gè)是可選參數(shù).

source_dir 源代碼目錄

指定一個(gè)包含CMakeLists.txt和代碼文件所在的目錄，該目錄可以是絕對(duì)路徑，也可以是相對(duì)路徑，對(duì)于后者相對(duì)路徑的起點(diǎn)是CMAKE_CURRENT_SOURCE_DIR。此外，如果子目錄再次包含的CMakeLists.txt，則將繼續(xù)處理里層的CMakeLists.txt，而不是繼續(xù)處理當(dāng)前源代碼。

binary_dir 二進(jìn)制代碼目錄

這個(gè)目錄是可選的，如果指定，cmake命令執(zhí)行后的輸出文件將會(huì)存放在此處，若沒(méi)有指定，默認(rèn)情況等于source_dir沒(méi)有進(jìn)行相對(duì)路徑計(jì)算前的路徑，也就是CMAKE_BINARY_DIR。

EXCLUDE_FROM_ALL標(biāo)記

這個(gè)標(biāo)志是可選的，如果傳遞了該參數(shù)表示新增加的子目錄將會(huì)排除在ALL目錄之外（可能是make系統(tǒng)中的make all？），表示這個(gè)目錄將從IDE的工程中排除。用戶必須顯式在子文件這個(gè)編譯目標(biāo)（手動(dòng)cmake之類的）。指定了這個(gè)文件夾，表示這個(gè)文件夾是獨(dú)立于源工程的，這些函數(shù)是有用但是不是必要的，比如說(shuō)我們一系列的例子。

add_subdirectory 這個(gè)命令用于添加源文件子目錄，同時(shí)還可以指定中間二進(jìn)制和目標(biāo)二進(jìn)制的生成路徑。EXCLUDE_FROM_ALL將會(huì)將這個(gè)目錄從編譯中排除，如工程的例子需要等待其他編譯完成后再進(jìn)行單獨(dú)的編譯。通常子目錄應(yīng)該包含自己的project()命令，這樣以來(lái)整個(gè)編譯命令將會(huì)產(chǎn)生各自的目標(biāo)文件。如果把CMakeLists.txt與VS IDE比較，總的CMakeLists.txt就相當(dāng)于解決方案，子CMakeLists.txt就相當(dāng)于在解決方案下的工程文件。還有一個(gè)需要注意的是，如果編譯父CMakeLists時(shí)依賴了子CMakeLists.txt中的源文件，那么該標(biāo)志將會(huì)被覆蓋（也就是也會(huì)處理），以滿足編譯任務(wù)。

這里指定src目錄下存放了源文件，當(dāng)執(zhí)行cmake時(shí)，就會(huì)進(jìn)入src目錄下去找src目錄下的CMakeLists.txt，所以在src目錄下也建立一個(gè)CMakeLists.txt，內(nèi)容如下:

src/CMakeLists.txt

set (EXECUTABLE_OUTPUT_PATH ${PROJECT_SOURCE_DIR}/bin)


這里的set其實(shí)是和前面的一樣，只是EXECUTABLE_OUTPUT_PATH是個(gè)系統(tǒng)自帶的預(yù)定義變量，其意義如下：

EXECUTABLE_OUTPUT_PATH ：目標(biāo)二進(jìn)制可執(zhí)行文件的存放位置

PROJECT_SOURCE_DIR：工程的根目錄

所以，這里set的意思是把存放elf文件的位置設(shè)置為工程根目錄下的bin目錄。（cmake有很多預(yù)定義變量，詳細(xì)的可以網(wǎng)上搜索一下）

添加好以上這2個(gè)CMakeLists.txt后，整體文件結(jié)構(gòu)如下：

4.3 運(yùn)行查看

下面來(lái)運(yùn)行cmake，不過(guò)這次先讓我們切到build目錄下:

cd build
cmake ..
make

這樣Makefile會(huì)在build目錄下生成，二進(jìn)制程序會(huì)在bin目錄下生成，然后運(yùn)行可執(zhí)行程序：

cd ../bin
./main

這里解釋一下為什么在build目錄下運(yùn)行cmake？還記得在第一個(gè)例子里我讓你著重看一下cmake和make之后會(huì)生成什么文件嗎？這個(gè)過(guò)程中會(huì)生成很多文件，但是可惜的是跟我們的運(yùn)行并沒(méi)有什么關(guān)系，因此，如果能把編譯隔離在某個(gè)文件夾，這樣cmake的時(shí)候所有的中間文件都將在這個(gè)目錄下生成，刪除的時(shí)候也很好刪除，非常方便。如果不這樣做，cmake運(yùn)行時(shí)生成的附帶文件就會(huì)跟源碼文件混在一起，這樣會(huì)對(duì)程序的目錄結(jié)構(gòu)造成污染。另外一種寫法：前面的工程使用了2個(gè)CMakeLists.txt，最外層的CMakeLists.txt用于掌控全局，使用add_subdirectory來(lái)控制其它目錄下的CMakeLists.txt的運(yùn)行。

上面的例子也可以只使用一個(gè)CMakeLists.txt，把最外層的CMakeLists.txt內(nèi)容改成如下

CMakeLists.txt

cmake_minimum_required (VERSION 2.8)

project (demo)

set (EXECUTABLE_OUTPUT_PATH ${PROJECT_SOURCE_DIR}/bin)

aux_source_directory (src SRC_LIST)

include_directories (include)

add_executable (main ${SRC_LIST})

同時(shí)，還要把src目錄下的CMakeLists.txt刪除。

然后正常編譯運(yùn)行就可以。

五 動(dòng)態(tài)庫(kù)和靜態(tài)庫(kù)的編譯控制

有時(shí)只需要編譯出動(dòng)態(tài)庫(kù)和靜態(tài)庫(kù)，然后等著讓其它程序去使用。讓我們看下這種情況該如何使用cmake。

5.1 生成庫(kù)文件

5.1.1 項(xiàng)目結(jié)構(gòu)

首先按照如下重新組織文件，只留下testFunc.h和TestFunc.c

我們會(huì)在build目錄下運(yùn)行cmake，并把生成的庫(kù)文件存放到lib目錄下。

5.1.2 示例源碼

CMakeLists.txt

cmake_minimum_required (VERSION 3.5)

project (demo)

set (SRC_LIST ${PROJECT_SOURCE_DIR}/testFunc/testFunc.c)

add_library (testFunc_shared SHARED ${SRC_LIST})
add_library (testFunc_static STATIC ${SRC_LIST})

set_target_properties (testFunc_shared PROPERTIES OUTPUT_NAME "testFunc")
set_target_properties (testFunc_static PROPERTIES OUTPUT_NAME "testFunc")

set (LIBRARY_OUTPUT_PATH ${PROJECT_SOURCE_DIR}/lib)

這里又出現(xiàn)了新的命令和預(yù)定義變量:

add_library: 生成動(dòng)態(tài)庫(kù)或靜態(tài)庫(kù)(第1個(gè)參數(shù)指定庫(kù)的名字；第2個(gè)參數(shù)決定是動(dòng)態(tài)還是靜態(tài)，如果沒(méi)有就默認(rèn)靜態(tài)；第3個(gè)參數(shù)指定生成庫(kù)的源文件)

set_target_properties: 設(shè)置最終生成的庫(kù)的名稱，還有其它功能，如設(shè)置庫(kù)的版本號(hào)等

LIBRARY_OUTPUT_PATH: 庫(kù)文件的默認(rèn)輸出路徑，這里設(shè)置為工程目錄下的lib目錄

PS：前面使用set_target_properties重新定義了庫(kù)的輸出名稱，如果不使用set_target_properties也可以，那么庫(kù)的名稱就是add_library里定義的名稱，只是連續(xù)2次使用add_library指定庫(kù)名稱時(shí)（第一個(gè)參數(shù)），這個(gè)名稱不能相同，而set_target_properties可以把名稱設(shè)置為相同，只是最終生成的庫(kù)文件后綴不同（一個(gè)是.so，一個(gè)是.a），這樣相對(duì)來(lái)說(shuō)會(huì)好看點(diǎn)。

5.1.3 運(yùn)行查看

cd build/
cmake ..
make
cd ../lib/
ls

5.2 鏈接庫(kù)文件

既然我們已經(jīng)生成了庫(kù)，那么就進(jìn)行鏈接測(cè)試下。

5.2.1 項(xiàng)目結(jié)構(gòu)

重新建一個(gè)工程目錄，然后把上節(jié)生成的庫(kù)拷貝過(guò)來(lái)，然后在在工程目錄下新建src目錄和bin目錄，在src目錄下添加一個(gè)main.c，整體結(jié)構(gòu)如下：

5.2.2 示例源碼

main.c

#include

#include "testFunc.h"

int main(void)
{
func(100);

return 0;
}

CMakeLists.txt

cmake_minimum_required (VERSION 3.5)

project (demo)


set (EXECUTABLE_OUTPUT_PATH ${PROJECT_SOURCE_DIR}/bin)

set (SRC_LIST ${PROJECT_SOURCE_DIR}/src/main.c)

# find testFunc.h
include_directories (${PROJECT_SOURCE_DIR}/testFunc/inc)

find_library(TESTFUNC_LIB testFunc HINTS ${PROJECT_SOURCE_DIR}/testFunc/lib)

add_executable (main ${SRC_LIST})

target_link_libraries (main ${TESTFUNC_LIB})

這里出現(xiàn)2個(gè)新的命令，

find_library: 在指定目錄下查找指定庫(kù)，并把庫(kù)的絕對(duì)路徑存放到變量里，其第一個(gè)參數(shù)是變量名稱，第二個(gè)參數(shù)是庫(kù)名稱，第三個(gè)參數(shù)是HINTS，第4個(gè)參數(shù)是路徑，其它用法可以參考cmake文檔

target_link_libraries: 把目標(biāo)文件與庫(kù)文件進(jìn)行鏈接

使用find_library的好處是在執(zhí)行cmake …時(shí)就會(huì)去查找?guī)焓欠翊嬖冢@樣可以提前發(fā)現(xiàn)錯(cuò)誤，不用等到鏈接時(shí)。

5.2.3 運(yùn)行查看

cd到build目錄下，然后運(yùn)行cmake … && make，最后進(jìn)入到bin目錄下查看，發(fā)現(xiàn)main已經(jīng)生成，運(yùn)行之：

cd build/
cmake ..
make
cd ../bin/
./main

ps：在lib目錄下有testFunc的靜態(tài)庫(kù)和動(dòng)態(tài)庫(kù)，find_library(TESTFUNC_LIB testFunc…默認(rèn)是查找動(dòng)態(tài)庫(kù)，如果想直接指定使用動(dòng)態(tài)庫(kù)還是靜態(tài)庫(kù)，可以寫成find_library(TESTFUNC_LIBlibtestFunc.so …或者find_library(TESTFUNC_LIB libtestFunc.a …

ps：查看elf文件使用了哪些庫(kù)，可以使用readelf -d ./xx來(lái)查看 例：readelf -d ./main

六 條件編譯

有時(shí)編譯程序時(shí)想添加一些編譯選項(xiàng)，如-Wall，-std=c++11等，就可以使用add_compile_options來(lái)進(jìn)行操作。這里以一個(gè)簡(jiǎn)單程序來(lái)做演示。

6.1 簡(jiǎn)單程序

6.1.1 項(xiàng)目結(jié)構(gòu)

6.1.2 示例代碼

main.cpp

#include

int main(void)
{
auto data = 100;
std::cout << "data: " << data << "\n";
return 0;
}

CMakeLists.txt

cmake_minimum_required (VERSION 2.8)

project (demo)

set (EXECUTABLE_OUTPUT_PATH ${PROJECT_SOURCE_DIR}/bin)

add_compile_options(-std=c++11 -Wall)

add_executable(main main.cpp)

6.1.3 運(yùn)行查看

然后cd到build目錄下，執(zhí)行cmake … && make命令，就可以在bin目錄下得到main的可執(zhí)行文件

6.2 添加編譯選項(xiàng)

有時(shí)希望在編譯代碼時(shí)只編譯一些指定的源碼，可以使用cmake的option命令，主要遇到的情況分為2種：

本來(lái)要生成多個(gè)bin或庫(kù)文件，現(xiàn)在只想生成部分指定的bin或庫(kù)文件

對(duì)于同一個(gè)bin文件，只想編譯其中部分代碼（使用宏來(lái)控制）

6.2.1 生成部分指定bin或庫(kù)文件

6.2.1.1 項(xiàng)目結(jié)構(gòu)

假設(shè)我們現(xiàn)在的工程會(huì)生成2個(gè)bin文件，main1和main2，項(xiàng)目結(jié)構(gòu)如下：

6.2.1.2 示例源碼

CMakeLists.txt

cmake_minimum_required(VERSION 3.5)

project(demo)

option(MYDEBUG "enable debug compilation" OFF)

set (EXECUTABLE_OUTPUT_PATH ${PROJECT_SOURCE_DIR}/bin)

add_subdirectory(src)

這里使用了option命令，其第一個(gè)參數(shù)是這個(gè)option的名字，第二個(gè)參數(shù)是字符串，用來(lái)描述這個(gè)option是來(lái)干嘛的，第三個(gè)是option的值，ON或OFF，也可以不寫，不寫就是默認(rèn)OFF。

然后編寫src目錄下的CMakeLists.txt，如下：

src/CMakeLists.txt

cmake_minimum_required (VERSION 3.5)

add_executable(main1 main1.c)

if (MYDEBUG)
add_executable(main2 main2.c)
else()
message(STATUS "Currently is not in debug mode")
endif()

注意，這里使用了if-else來(lái)根據(jù)option來(lái)決定是否編譯main2.c,其中main1.c和main2.c的內(nèi)容如下:

main1.c

// main1.c
#include

int main(void)
{
printf("hello, this main1\n");

return 0;
}

main1.c

// main2.c
#include

int main(void)
{
printf("hello, this main2\n");

return 0;
}

6.2.1.3 運(yùn)行查看

然后cd到build目錄下輸入cmake … && make就可以只編譯出main1，如果想編譯出main2，就把MYDEBUG設(shè)置為ON，再次輸入cmake … && make重新編譯。

每次想改變MYDEBUG時(shí)都需要去修改CMakeLists.txt，有點(diǎn)麻煩，其實(shí)可以通過(guò)cmake的命令行去操作，例如我們想把MYDEBUG設(shè)置為OFF，先cd到build目錄，然后輸入cmake … -DMYDEBUG=ON，這樣就可以編譯出main1和main2 （在bin目錄下）

6.2.2 編譯部分代碼

假設(shè)我們有個(gè)main.c，其內(nèi)容如下：

main.c

#include

int main(void)
{
#ifdef WWW1
printf("hello world1\n");
#endif

#ifdef WWW2
printf("hello world2\n");
#endif

return 0;
}

可以通過(guò)定義宏來(lái)控制打印的信息，我們CMakeLists.txt內(nèi)容如下:

cmake_minimum_required(VERSION 3.5)

project(demo)

set (EXECUTABLE_OUTPUT_PATH ${PROJECT_SOURCE_DIR}/bin)

option(WWW1 "print one message" OFF)
option(WWW2 "print another message" OFF)

if (WWW1)
add_definitions(-DWWW1)
endif()

if (WWW2)
add_definitions(-DWWW2)
endif()

add_executable(main main.c)

這里把option的名字保持和main.c里的宏名稱一致，這樣更加直觀，也可以選擇不同的名字。通過(guò)與add_definitions()的配合，就可以控制單個(gè)bin文件的打印輸出了。

整體工程結(jié)構(gòu)如下：

cd到build目錄下執(zhí)行cmake … && make，然后到bin目錄下執(zhí)行./main，可以看到打印為空，

接著分別按照下面指令去執(zhí)行，然后查看打印效果，

cmake … -DWWW1=ON -DWWW2=OFF && make

cmake … -DWWW1=OFF -DWWW2=ON && make

cmake … -DWWW1=ON -DWWW2=ON && make

這里有個(gè)小坑要注意下：假設(shè)有2個(gè)options叫A和B，先調(diào)用cmake設(shè)置了A，下次再調(diào)用cmake去設(shè)置B，如果沒(méi)有刪除上次執(zhí)行cmake時(shí)產(chǎn)生的緩存文件，那么這次雖然沒(méi)設(shè)置A，也會(huì)默認(rèn)使用A上次的option值。

所以如果option有變化，要么刪除上次執(zhí)行cmake時(shí)產(chǎn)生的緩存文件，要么把所有的option都顯式的指定其值。

總結(jié)

以上是自己學(xué)習(xí)CMake的一點(diǎn)學(xué)習(xí)記錄，通過(guò)簡(jiǎn)單的例子讓大家入門CMake，學(xué)習(xí)的同時(shí)也閱讀了很多網(wǎng)友的博客。CMake的知識(shí)點(diǎn)還有很多，具體詳情可以在網(wǎng)上搜索。

總之，CMake可以讓我們不用去編寫復(fù)雜的Makefile，并且跨平臺(tái)，是個(gè)非常強(qiáng)大并值得一學(xué)的工具。

審核編輯：湯梓紅